Useful string jumbler function

[Rob]

Someone wanted a function to take a comma seperated string and jumble the items around into a different order. I thought I would share this all with you incase it would become handy.

I knocked this up in a few minutes, so apologies if anything is bugged.

Code: Select all

Function jumbleStringArray(strItems, strSeperator)
	Dim TempFlag1, TempFlag2, TempStr, ItemArray
	ItemArray = Split(StrItems,strSeperator)
	For Counter = 0 to (ubound(ItemArray)) * 5
		TempFlag2 = 999999999
		Randomize()
		TempFlag1 = int((ubound(ItemArray)+1)*rnd())
		do
			Randomize
			TempFlag2 = int((ubound(ItemArray)+1)*rnd())
		loop Until TempFlag2 <> TempFlag1
		TempStr = ItemArray(TempFlag1)
		ItemArray(TempFlag1) = Trim(ItemArray(TempFlag2))
		ItemArray(TempFlag2) = Trim(TempStr)
	Next
	TempStr=""
	For Counter = 0 to ubound(ItemArray)
		TempStr = TempStr & ItemArray(Counter) & ","
	Next
	TempStr = left(TempStr,len(TempStr)-1)
	jumbleStringArray = TempStr
End Function

[Smokie]

[Nick]

Cool code. A few points (I'm being rather picky here):
- The last 6 lines can be replaced with jumbleStringArray = Join(ItemArray(Counter), ",")
- Why Randomize so much? Just one at the start of the function does exactly the same.
- The tempflag2 = 999999999 isn't needed.
- Why the do-loop bit in the middle? If it's random then it should allow a swap of index 3 with index 3, for example.
- I'd make the * 5 actually based on the size of the array - doing 5 loops wouldn't be sufficient on a large array.
- Doing it this way obviously wouldn't be wholey random - there are much slicker solutions for properly randomizing.

Here's mine, it's not optimised (the keep-looping-till-we-get-an-unused-index bit is rather crappy) but it seems to run fast enough. Should be perfectly random:

Code: Select all

Option Explicit
Function JumbleStringArray(strItems, strSeperator)
	Randomize()
	Dim aryStart, intArraySize, aryResult, aryUsedIndexes, intCounter, intRndIndex, i
	aryStart = split(strItems, strSeperator)
	intArraySize = ubound(aryStart)
	ReDim aryResult(intArraySize)
	Redim aryUsedIndexes(intArraySize)
	For i = intCounter to intArraySize
		Do
			intRndIndex = int(rnd() * (intArraySize + 1))
		Loop Until aryUsedIndexes(intRndIndex) = ""
		aryResult(intRndIndex) = aryStart(i)
		aryUsedIndexes(intRndIndex) = "y"		
	Next
	JumbleStringArray = Join(aryResult, strSeperator)
End Function

[Smokie]

[Rob]

Hi... <blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote">The tempflag2 = 999999999 isn't needed.
<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">I actually used a do while loop initially, so I guess I forgot to take this out.<blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote">Why the do-loop bit in the middle? If it's random then it should allow a swap of index 3 with index 3, for example.<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">Just my personal preference, thats all.<blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote">I'd make the * 5 actually based on the size of the array - doing 5 loops wouldn't be sufficient on a large array.<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">If you look again, it IS based on the size of the array.... 5 * the number of elements in the array to be precise.<blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote">Why Randomize so much? Just one at the start of the function does exactly the same.<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">LOL... that was supposed to be outside of the for loop. Well Spotted! (I did say I knocked it up rather quickly)<blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote">Join(aryResult, strSeperator)<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">Kewl.... never come across that one before. I coulda saved SOOO much time in the past.

And you are right.... yer a picky sod.

Next time I submt some code, I shall endeavour to pick my brains for hours before-hand to make it as good as possible and not open to nit picks like you!! ROFLMAO