Template Processing

[vor]

I'm writing another template reading. This time around I'm making the template file XML based. The basis of this class is to open a xml and process the custom tags "template" and "item".

The only draw back is that all the HTML you use in the template has to follow XML rules. Case sensitive and close every tag. But the bright side is that it makes it easy for any none technical people to modify the template and do little to no asp code change.

Currently, this class can only process a multi-dimensional array. But I will be adding a Auto Request.Form and Recordset processing. Then finish this bad boy with a send html/text email from the processed template.

Thought some of you might want to take the basic concept and build the rest on your own or what not. Either way, On With the CoDe..

ASP CLASS AND USAGE CODE

Code: Select all

<%
'vTemplate by Pedro "VoR" Sousa

dim tmpl
set tmpl = new vTemplate
if not tmpl.Load(Server.MapPath("tmpl_form.xml")) then
	Response.write "Unable to load template. Either file not found, or there is an error in the xml file."
else '++++++++++++++++++++++++++++++++++++++++
	dim ary(1)
	ary(0) = Array("item1","item 1 text")
	ary(1) = Array("item2","item 2 text")
	call tmpl.ProcessArray("tmp1",ary)
	Response.write tmpl.Output()
end if
tmpl.Close()
set tmpl = nothing

class vTemplate
	'##########################################
	'Private Global Variables
	'##########################################
	private xml
	
	'##########################################
	'Main Functions
	'##########################################
	private sub class_initialize()
		set xml = Server.CreateObject("Microsoft.XMLDOM")
		xml.async = false
	end sub'-----------------------------------------------
	
	private sub class_terminate()
		set xml = nothing
	end sub'-----------------------------------------------
	
	public function Load(path)
		Load = xml.Load(path)
	end function'------------------------------------------
	
	public sub Close()
		set xml = nothing
	end sub'-----------------------------------------------
	'##########################################
	'Processing Function
	'##########################################
	'Get the Template Output after processing
	public function Output()
		Output = xml.documentElement.xml
		'Clean up some unwanted text
		Output = replace(output,"<template>","")
		Output = replace(output,"</template>","")
		Output = replace(output,"<TemplateDocument>","")
		Output = replace(output,"</TemplateDocument>","")
	end function'------------------------------------------
	
	'Process a MultiDimensional Array
	public function ProcessArray(tname,ary)
		ProcessArray = false
		if not isArray(ary) then exit function
		dim tnode,nl,n
		set tnode = FindTemplate(lcase(tname))
		if not tnode is nothing then 'If template Node found
			RemoveAttribs(tnode) 'Lets get ride of all attributes.
			set nl = tnode.getElementsByTagName("item")
			if nl.length > 0 then
				for each n in nl
					if n.getAttribute("id") <> "" then
						call ProcessItem(n,FindArrayValue(n.getAttribute("id"),ary))
					end if
				next
			end if
			set nl = nothing
		end if
		set tnode = nothing
	end function'------------------------------------------

	'##########################################
	'Helper Functions
	'##########################################
	'Find a Template Element by ID
	private function FindTemplate(tname)
		set FindTemplate = nothing
		dim n,nl: set nl = xml.getElementsByTagName("template")
		if nl.length > 0 then
			for each n in nl
				if lcase(n.getAttribute("id")) = tname then set FindTemplate = n : exit for
			next
		end if
		set nl = nothing
	end function'------------------------------------------
	
	'Search through a MultiDimensional Array for ID-Value pair.
	private function FindArrayValue(id,ary)
		FindArrayValue = ""
		dim x
		for x = 0 to ubound(ary)
			if ary(x)(0) = id then FindArrayValue = ary(x)(1) : exit function
		next
	end function'------------------------------------------
	
	'Remove all the attrbutes of a node
	private sub RemoveAttribs(node)
		dim a
		for each a in node.attributes
			node.removeAttributeNode(a)
		next
	end sub'-----------------------------------------------
	
	'Process the Item Node
	private sub ProcessItem(node,text)
		dim content,txtnode
		'If no data is sent, Lets grab and default info stored in the item
		if text <> "" then content = text else content = node.getAttribute("default")
		'Now Replace Node with text
		call node.parentNode.replaceChild(xml.createTextNode(content),node)
	end sub'-----------------------------------------------
end cla

XML TEMPLATE FILE

Code: Select all

<?xml version="1.0"?>
<TemplateDocument>
<html>
	<head>
		<title>vTemplate by Pedro "vor" Sousa</title>
	</head>
<body>

<template id="tmp1">
	<table border="1" cellpadding="9">
		<tr><td><item id="item1" default="default value1"/></td></tr>
		<tr><td><item id="item2" default="default value2"/></td></tr>
		<tr><td><item id="item3" default="Using Default Value"/></td></tr>
	</table>
</template>

</body>
</html>
</TemplateDocument>

[u2orange]

In your 'Output' function why have you used 'Output = replace(output,"","")' four times, won't one have done?

u2o

[Rob]

<blockquote id="quote"><font size="1" face="geneva, verdana, arial" id="quote">quote:<hr height="1" noshade id="quote"> In your 'Output' function why have you used 'Output = replace(output,"","")' four times, won't one have done?
<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">

Actually, that code does nothing, but I think Vor's intention is for you to fill in the processing section yourself!!

I actually have what I consider to be a much better templating system than this (Not to knock Vor's way, but mine has been kicking around for ages, and has been built upon for a few years now), which will process either a standard HTML template, or an XHTML compliant template and allowing for dynamic content anywhere in the template including the Head section... header content and footer (In fact anywhere).... I will get round to posting it as soon as I get time... I am up to deadline on 3 sites at the moment and am a bit pushed!

Giving it away now are we!? I'll be looking for it. My version is outdated now. :razz: